EnigmA Amiga Run 1996 March/EnigmA AMIGA RUN 05 (1996)(G.R. Edizioni)(IT)[!][issue 1996-03][Skylink CD IV].iso/earcd/program/amcfp140.lha/AMCAF_Examples/FileRequester.AMOS/FileRequester.amosSourceCode

AMOS Source Code | 1996-01-19 | 34KB | 1,269 lines

' *************************************
' *                                   *
' *     AMCAF File-Requester V1.2     *
' *        NOW NTSC COMPATIBLE!       *
' *      Written by Chris Hodges      *
' *                                   *
' *************************************
'
' FILEREQ[screen,width,height,ypos,title$,file$,dir$,pat$,ok$,abort$,font$,options$]
'
'   Opens a font sensitive, very nice file-requester.
'
'�  Screen   Any screen number from 0 to 7. When using -1, the file requester
'            will take a free one.
'   Width    Width of the requester from 160 to 640. The screen will be
'            centered automatically.
'   Height   Height of the file requester. The minimum is 96 and the maximum
'            256.
'   Ypos     Gives your control over the position of the selector. If it is
'            set to zero, the requester will be centered on the screen.
'   Title$   Screen title.
'   File$    Default filename.
'   Dir$     Default directory. If none is given, the current directory will
'            be taken instead.
'   Pat$     Searching pattern string. This filters the files in the
'            selection window. Pattern matching works only on Kick 2.04 and
'            over. Note, that if you don't have Option 'P' enabled, the user
'            cannot alter this pattern.
'   Ok$      The text, that appears in the positive button.
'   Abort$   The text, that is shown in the negative button.
'   Font$    Let's you use any font you want. If you select an other bigger
'            font, change the dimensions of the screen respectively.
'            The font must be entered like so: two digits height and then the
'            name: e.g "24Helvetica" or "11Topaz".
'            There are a few problems with proportional fonts, but they will
'            work as well.
'            When Font$ is an empty string, normal Topaz 8 will be chosen.
'
'   Options$ Contains some letters with enable or disable a particular
'            function. Possible options:
'
'            P=Enable Pattern Matching Box. The user now may edit the pattern.
'            R=Reread directory on opening. Should be used e.g after saving.
'            D=Lists directories only.
'              Only use it in conjunction with the R-Option.
'              Disable the pattern matching box, as it has no function anymore.
'            Q=Disables Date, Time, and Comment strings.
'            S=Disables double clicking (e.g for Save-Requesters).
'
' FILEREQNOTIFY
'
'   Clears the current filelist because it's not up to date. (e.g
'   after saving).
'
' REQUESTER[body$,choices$]
'
'   Opens a requester on the current screen, or if it doesn't fit, it opens
'   the dialogbox on the next free screen. The result is given in Param.
'
'   Body$    Contains the title text of the dialogbox. The text will be word
'            wrapped to fit.
'   Choices$ Contains the different choices for this requester. The single
'            items must be seperated by an "|" character.
'
' Use the other procedures as you like, but don't use the buttons from 1 to
' 25 for your programs.
'
' Short explainations of the other procedures:
'
' CHKMOUSE[xm,ym,lower,upper]
'
'   Checks if the mouse is inside a button. Xm,ym are the mouse coordinates
'   on the screen. Lower represents the first button to be checked and upper
'   the last one. The function will return the button number pressed or 0, if
'   no button has been clicked on. Normally, this procedure includes the
'   graphical echo and so on, but this can be disabled by setting bit 1 in
'   the button flags.
'
' DEFTEX[bt,x1,y1,x2,y2,t$,fl]
'
'   Defines a text button. bt is the button number. x1,y1 to x2,y2 define the
'   dimensions of the button. t$ is used for the button text. Note that it
'   will be shortened, if it doesn't fit, so you'll never get any graphical
'   mess on the screen. fl are the button flags:
'
'   Bit 0=0: Button is disabled. The user cannot click on it.
'   Bit 0=1: Button is enabled. The user can press the button as he wants to.
'   Bit 1=0: CHKMOUSE will to the graphical response for the button.
'   Bit 1=1: Special Button: the CHKMOUSE routine will return immediately.
'   Bit 2=0: Button is drawn in normal video.
'   Bit 2=1: The button will be drawn as pressed in inverse video.
'
'   Also there are some options for the displayed text: If the first letter
'   contains a "{" character, the text will be put out left justified.
'   Same with "}", but this time the text will be right justified.
'
'   These flags and textoptions are available in every procedure, that uses
'   these variables.
'
' DEFBOX[bt,x1,y1,x2,y2,fl]
'
'   Defines an empty box as a gadget on the screen. See DEFTEX.
'
' DEFGAD[bt,x1,y1,x2,y2,fl]
'
'   Sets up a invisible button. Use it in conjunction with the Bit 2 flag.
'
' DEAGAD[bt]
'
'   Ghosts a button out and disables it, so it cannot be clicked on anymore.
'
' ACTGAD[bt]
'
'   Re-activates a button again. It will be redrawn with known information.
'
' DISGAD[bt]
'
'   Deactivates a gadget, but does not change the graphics. Use it for
'   borderless zones.
'
' ENAGAD[bt]
'
'   Enables a button again, which was previously deactivated by the DISGAD
'   procedure. No graphical change is done.
'
' CLRGAD[bt]
'
'   Clears an disables a button on the screen.
'
' PUSHGAD[bt]
'
'   Pushes a button in.
'
' RELEGAD[bt]
'
'   Releases the gadget again.
'
' FILBOX[x1,y1,x2,y2,se]
'
'   Draws a filled bevel box, which will not be included as real gadget.
'   x1,y1 to x2,y2 define the dimensions. If se is set to zero, the box
'   will be drawn as normal, if se is 1, the box will be drawn inverse.
'
' NEWTEX[bt,t$]
'
'   Changes the text inside a button. The button will be updated
'   immediately.
'
' TEXBOX[x1,y1,x2,y2,se,t$]
'
'   Draws a gadgetbox with some text in it. Like FILBOX, this does not set up
'   a clickable gadget. t$ will be cut off, if the text does not fit.
'
' TEX[x1,y1,x2,y2,t$]
'
'   Prints out a text, which will be placed inside the rectangular area
'   x1,y1 to x2,y2.
'
' DRABOX[x1,y1,x2,y2,se]
'
'   Draws the borders of a bevel box. If se is set to 1, the box will be drawn
'   as if it has been pressed.
'
' STRGAD[bt,i$]
'
'   Allows the user to modify the button text. I$ contains the key, that
'   has been entered into the keyboard. If i$ is an empty string, the
'   cursor position will be set to the end of the line.
'   If the user has pressed the return key, the resulting parameter will be
'   -1 otherwise 0.
'
' DEFCLOWIN[bt,x,y]
'
'   Draws and defines a CloseWindow-Gadget at coordinates x,y.
'
' DRACLOWIN[x,y]
'
'   Only draws a CloseWindow-Gadget.
'
' DEFSCRTBK[bt,x,y]
'
'   Draws and defines a ScreenToBack-Gadget at coordinates x,y.
'
' DRASCRTBK[x,y]
'
'   Only draws a ScreenToBack-Gadget.
'
' DEFARROWU[bt,x,y]
'
'   Draws and defines a ArrowUp-Gadget at coordinates x,y.
'
' DRAARROWU[x,y]
'
'   Only draws a ArrowUp-Gadget.
'
' DEFARROWD[bt,x,y]
'
'   Draws and defines a ArrowDown-Gadget at coordinates x,y.
'
' DRAARROWD[x,y]
'
'   Only draws a ArrowDown-Gadget.
'
' DRASLIDER[bt,lineoff,pagesize,maxlines,obt]
'
'   Sets up a slider bar. Therefore gadget obt will be used to create the new
'   Button bt. For checking reasons, obt must be lower than bt.
'   Lineoff sets the current position of the slider. Pagesize defines the
'   size of the slider in units. Maxlines sets the total amount of possible
'   positions.
'
' DRAGSLIDER[bt,y,pagesize,maxlines,obt]
'
'   Drags a slider to a new position. Therefore you must supply the position
'   of the slider handle. Lineoff is returned via Param.
'
Set Buffer 40
If Screen<>-1 Then Screen Close 0
MXFILES=300
Dim FIL$(MXFILES)
'
Dim FB(25,4),FB$(25)
Global FB(),FB$()
TH=8
Global TH
FILEREQ[0,640,256,0,"Load a blab.","","","","Load","Abort","",""]
F$=Param$
REQUEST["You've selected file '"+ Extension_8_02F0(F$)+"' in drawer '"+ Extension_8_03E0(F$)+"', correct?","How did you know that?|Really marvellous!"]
REQUEST["Do you have enjoyed this demonstation?","Yes of course!|Rather boring!|Silly!"]
End
Procedure FILEREQNOTIFY
  Shared FIL$()
  FIL$(0)=""
End Proc
Procedure FILEREQ[SN,SX,SY,YP,T$,F$,D$,PAT$,OK$,FAIL$,FON$,OP$]
  Shared FIL$(),MXFILES
  OTH=TH
  Gosub INIT
  Gosub SETUPSCREEN
  Gosub REFRESH
  Multi Wait : Limit Mouse
  OMK=0 : EXA=0 : ENT=0
  Do
    If Timer>25 and RDIR=1
      Sort FIL$(0)
      Gosub REFRESH
      Timer=0
    End If
    Repeat
      If RDIR Then Gosub EXAMINDIR Else Multi Wait
    Until Amos Here
    XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse) : MK=Mouse Key : I$=Inkey$
    If MK=2 Then Gosub DEVLIST
    If I$<>"" and ENT>0
      STRGAD[ENT,I$]
      If Param=-1
        If ENT=6
          F$=Mid$(FB$(6),2) : BT=4
          FIL$(0)= Extension_8_08C4(FILOFF)+ Extension_8_08C4(MXNAMLEN)+RDIR$
          Exit
        End If
        If ENT=7
          DD$=D$
          D$=Mid$(FB$(7),2)
          If Exist(D$)
            Gosub NEWREAD
          Else
            REQUEST["Directory "+D$+" not found!","Oh sorry!"]
            D$=DD$
            NEWTEX[7,"{"+D$]
          End If
        End If
        If ENT=8
          PAT$=Mid$(FB$(8),2)
          Gosub NEWREAD
        End If
        ENT=0
      End If
    End If
    BT=0
    If MK=1 and OMK<>1
      CHKMOUSE[XM,YM,1,15]
      BT=Param
    End If
    If BT and ENT Then NEWTEX[ENT,FB$(ENT)] : ENT=0
    If BT=1 Then Gosub DRAGSCREEN
    If BT=11 Then Gosub SELECT
    If BT=2 or BT=4 or BT=5
      If RDIR
        FIL$(0)=""
      Else
        FIL$(0)= Extension_8_08C4(FILOFF)+ Extension_8_08C4(MXNAMLEN)+RDIR$
      End If
      Exit
    End If
    If BT=3 Then Amos To Back
    If BT>5 and BT<9 Then ENT=BT : STRGAD[BT,""]
    If BT=9 Then Gosub DEVLIST
    If BT=10 Then Gosub PARDIR
    If BT=12 Then Gosub DRAGSLIDER
    If BT=13 Then Gosub ARROWUP
    If BT=14 Then Gosub ARROWDOWN
    If BT=15 Then Gosub FLIPPAGE
    OMK=MK
  Loop
  Screen Close SN
  For A=1 To 15
    DISGAD[A]
  Next
  If BT=4 Then A$= Extension_8_03EC(D$)+F$ Else A$=""
  TH=OTH
  Trap Limit Mouse
Pop Proc[A$]
INIT:
  If SN<0
    For A=0 To 7
      Trap Screen A
      If Errtrap : SN=A : Exit : End If
    Next
  End If
  If T$="" Then T$="AMCAF File Selector"
  If D$="" Then D$= Extension_8_03E0(Dir$)
  If Instr(OP$,"P") Then PAT=1 Else PAT=0
  If Instr(OP$,"R") Then FIL$(0)=""
  If Instr(OP$,"D") Then DIONLY=1 Else DIONLY=0
  If Instr(OP$,"Q") Then QUICK=1 Else QUICK=0
  If Instr(OP$,"S") Then SAVREQ=1 Else SAVREQ=0
  KICK=Deek(Leek(4)+20)
  If KICK<37 Then PAT=0
  SX=Max(Min((SX+15) and $FFE0,640),160)
  SY=Max(Min(SY,256+Ntsc*56),96)
  If YP<40 Then YP=168-SY/2+Ntsc*28
  If FIL$(0)<>""
    RDIR$=Mid$(FIL$(0),5)
    If D$<>RDIR$
      FIL$(0)=""
      RDIR=1 : NUMFIL=0 : FILOFF=0
      Return
    End If
    For A=1 To MXFILES
      Exit If FIL$(A)=Chr$(255)
    Next
    SELFIL=-1 : NUMFIL=A-1 : FILOFF= Extension_8_098C(FIL$(0))
    MXNAMLEN= Extension_8_098C(Mid$(FIL$(0),3))
    RDIR=0
  Else
    RDIR=1 : NUMFIL=0 : FILOFF=0 : SELFIL=-1
  End If
Return
SETUPSCREEN:
  Screen Open SN,SX,SY,4,$8000
  Curs Off : Flash Off : Paper 2 : Pen 1 : Cls 0
  Palette 0,$FFF,$AAA,$666
  Colour 17,$BDF : Colour 18,$6F : Colour 19,$12
  Screen Display SN,288-SX/4,YP,SX,SY
  If FON$<>""
    A=Val(Left$(FON$,2))
    If A>0
      Trap Extension_8_05B0 Mid$(FON$,3),A
      If Errtrap=0
        TH=A
      End If
    End If
  End If
  Gr Writing 0
  DEFCLOWIN[2,0,0]
  FILBOX[0,TH+3,SX-1,SY-1,0]
  DEFTEX[1,19,0,SX-24,TH+2,"{"+T$,3]
  DEFSCRTBK[3,SX-23,0]
  A=Text Length("Pattern:")+8
  If DIONLY=0
    DEFTEX[6,A,SY-TH*2-9,SX-5,SY-TH-7,"{"+F$,7]
    TEX[4,FB(6,1),FB(6,0),FB(6,3),"}File:"]
    FY2=SY-TH*3-13
  Else
    FY2=SY-TH*2-9
  End If
  DEFTEX[7,A,FY2,SX-5,FY2+TH+2,"{"+D$,7]
  TEX[4,FB(7,1),FB(7,0),FB(7,3),"}Dir:"]
  If PAT
    DEFTEX[8,A,FY2-TH-4,SX-5,FY2-2,"{"+PAT$,7]
    TEX[4,FB(8,1),FB(8,0),FB(8,3),"}Pattern:"]
    FY2=FB(8,1)-2
  Else
    FY2=FB(7,1)-2
  End If
  DEFTEX[4,4,SY-TH-5,SX/4-2,SY-3,OK$,1]
  DEFTEX[9,SX/4+1,SY-TH-5,SX/2-3,SY-3,"Devices",1]
  DEFTEX[10,SX/2,SY-TH-5,SX/2+SX/4-4,SY-3,"Parent",1]
  If Right$(D$,1)=":" Then DEAGAD[10]
  DEFTEX[5,SX/2+SX/4-1,SY-TH-5,SX-5,SY-3,FAIL$,1]
  DEFARROWU[13,SX-22,FY2-17]
  DEFARROWD[14,SX-22,FY2-8]
  D=(FY2-TH-9)
  MXLIN=D/TH
  FY1=TH+7+(D-TH*MXLIN)/2
  DEFBOX[15,SX-22,TH+5,SX-5,FY2-18,3]
  DRASLIDER[15,FILOFF,MXLIN,NUMFIL,12]
Return
PARDIR:
  If Right$(D$,1)=":" Then Return
  If RDIR Then Extension_8_0660
  D$= Extension_8_03E0(D$)
  Gosub NEWREAD
Return
NEWREAD:
  If RDIR Then Extension_8_0660
  NEWTEX[7,"{"+D$]
  EXA=0 : RDIR=1 : Gosub EXAMINDIR
  If Right$(D$,1)=":" Then DEAGAD[10] Else ACTGAD[10]
  ACTGAD[9]
Return
DEVLIST:
  If RDIR=1 or Left$(FIL$(NUMFIL),1)>="A" Then Return
  FILOFF=NUMFIL
  F$=Dev First$("")
  While NUMFIL<MXFILES and(F$<>"")
    F$=Mid$(F$,2,Instr(F$,":")-1)
    TYP= Extension_8_02D0(F$)
    If TYP=0
      MXNAMLEN=Max(MXNAMLEN,Len(F$))
      Request Off
      Trap Extension_8_0672 F$
      A=Errtrap
      Request On
      If A=0
        NAM$= Extension_8_06D8
        SOR$="A"+Upper$(F$)+Chr$(0)+"  <Dev> "+F$+Chr$(0)+" ("+NAM$+") "
      Else
        SOR$="A"+Upper$(F$)+Chr$(0)+"  <Dev> "+F$+Chr$(0)+" "+ Extension_8_0522( Extension_8_0532 )
      End If
      Inc NUMFIL
      FIL$(NUMFIL)=SOR$
    End If
    If TYP=1
      MXNAMLEN=Max(MXNAMLEN,Len(F$))
      Inc NUMFIL
      FIL$(NUMFIL)="B"+Upper$(F$)+Chr$(0)+"  <Dir> "+F$+Chr$(0)+" Assign"
    End If
    F$=Dev Next$
  Wend
  Sort FIL$(0)
  FILOFF=Min(FILOFF,NUMFIL-MXLIN)
  Gosub REFRESH
  DEAGAD[9]
Return
SELECT:
  Y=YM-FY1
  If Y<0 or Y>=FY1+MXLIN*TH Then Return
  F=Y/TH+FILOFF+1
  If F>NUMFIL Then Return
  TYP=Asc(FIL$(F))
  A$=Peek$(Varptr(FIL$(F))+Instr(FIL$(F),Chr$(0))+8,40,Chr$(0))
  If TYP=32
    D$= Extension_8_03EC(D$)+A$
    Gosub NEWREAD
  End If
  If TYP=45
    F$=A$
    NEWTEX[6,"{"+F$]
    If SELFIL<>F
      If SELFIL-FILOFF=>0 and SELFIL-FILOFF<=MXLIN
        A=SELFIL-FILOFF-1 : SELFIL=-1
        Gosub LISTFILE
      End If
      SELFIL=F : A=SELFIL-FILOFF-1 : Timer=0
      Gosub LISTFILE
    Else
      If Timer<50 and SAVREQ=0
        BT=4
      End If
    End If
  End If
  If TYP=65 or TYP=66
    D$=A$ : Gosub NEWREAD
  End If
Return
DRAGSCREEN:
  PUSHGAD[BT]
  A=YM
  Limit Mouse X Hard(0),40+A To X Hard(SX-1),296-SY+A+Ntsc*56
  Repeat
    If RDIR : Gosub EXAMINDIR : Else Multi Wait : End If
    YM=Y Screen(Y Mouse)-A : MK=Mouse Key : I$=Inkey$
    Add YP,YM
    Screen Display SN,,YP,,
  Until MK<>1
  Multi Wait : Limit Mouse
  OMK=1
  RELEGAD[BT]
Return
ARROWUP:
  PUSHGAD[BT]
  Repeat
    Multi Wait
    MK=Mouse Key : I$=Inkey$
    If FILOFF>0
      Dec FILOFF
      Gosub SCROLFILES
    End If
  Until MK<>1
  RELEGAD[BT]
Return
ARROWDOWN:
  PUSHGAD[BT]
  Repeat
    Multi Wait
    MK=Mouse Key : I$=Inkey$
    If FILOFF<NUMFIL-MXLIN
      Inc FILOFF
      Gosub SCROLFILES
    End If
  Until MK<>1
  RELEGAD[BT]
Return
DRAGSLIDER:
  DISGAD[12]
  O=YM-FB(12,1)
  Repeat
    Multi Wait
    XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse) : MK=Mouse Key : I$=Inkey$
    DRAGSLIDER[15,YM-O,MXLIN,NUMFIL,12]
    If NUMFIL>MXLIN
      FILOFF=Param
      Gosub SCROLFILES
    End If
  Until MK<>1
  ENAGAD[12]
  DRASLIDER[15,FILOFF,MXLIN,NUMFIL,12]
  OMK=1
Return
REFRESH:
  DEFBOX[11,4,TH+5,SX-25,FY2,7]
  If NUMFIL>0
    For A=0 To Min(MXLIN-1,NUMFIL-1)
      Gosub LISTFILE
    Next
    OLDOFF=FILOFF
  End If
  If FB(12,4) and 1 Then DRASLIDER[15,FILOFF,MXLIN,NUMFIL,12]
Return
SCROLFILES:
  If OLDOFF=FILOFF Then Return
  X1=FB(11,0)+2 : X2=FB(11,2)-2 : Y1=FY1+1 : Y2=FY1+TH*MXLIN+1
  D=FILOFF-OLDOFF
  If Abs(D)>MXLIN-2 Then Gosub REFRESH : Return
  If D>0
    Screen Copy SN,X1,Y1+D*TH,X2,Y2 To SN,X1,Y1
    For A=MXLIN-D To MXLIN-1
      Gosub LISTFILE
    Next
  Else
    Screen Copy SN,X1,Y1,X2,Y2+D*TH To SN,X1,Y1-D*TH
    For A=0 To -D-1
      Gosub LISTFILE
    Next
  End If
  OLDOFF=FILOFF
  If FB(12,4) and 1 Then DRASLIDER[15,FILOFF,MXLIN,NUMFIL,12]
Return
FLIPPAGE:
  If NUMFIL<MXLIN Then Return
  If YM>(FB(12,1)+FB(12,3))/2
    FILOFF=Min(FILOFF+MXLIN,NUMFIL-MXLIN)
  Else
    FILOFF=Max(FILOFF-MXLIN,0)
  End If
  Gosub REFRESH
  DRASLIDER[15,FILOFF,MXLIN,NUMFIL,12]
Return
LISTFILE:
  If QUICK
    A$=FIL$(A+FILOFF+1)
    A$=Peek$(Varptr(A$)+Instr(A$,Chr$(0)),40,Chr$(0))
  Else
    A$=FIL$(A+FILOFF+1)
    B$=Mid$(A$,Instr(A$,Chr$(0))+1)
    FIL$=Left$(B$,Instr(B$,Chr$(0))-1)
    RES$=Mid$(B$,Len(FIL$)+2)
    A$=FIL$+Space$(MXNAMLEN-(Len(FIL$)-8))+RES$
  End If
  If Asc(FIL$(A+FILOFF+1))<>45
    TEX2[6,FY1+A*TH,SX-28,FY1+(A+1)*TH+1,"{"+A$]
  Else
    TEX[6,FY1+A*TH,SX-28,FY1+(A+1)*TH+1,"{"+A$]
  End If
  If A+FILOFF+1=SELFIL
    Gr Writing 2
    Ink 2 : Bar 8,FY1+A*TH+1 To SX-29,FY1+(A+1)*TH
    Gr Writing 0
  End If
Return
EXAMINDIR:
  If EXA=0
    FILOFF=0 : NUMFIL=0 : MXNAMLEN=5 : RDIR$=D$
    SELFIL=-1
    For A=1 To MXFILES
      FIL$(A)=Chr$(255)
    Next
    Trap Extension_8_063A D$
    If Errtrap=0
      EXA=1 : Timer=0
    Else
      Gosub REFRESH
      REQUEST[ Extension_8_0522( Extension_8_0532 )+"!","Cancel"]
      RDIR=0 : Return
    End If
  End If
  If NUMFIL=MXFILES
     Extension_8_0660
    Sort FIL$(0)
    RDIR=0
    Gosub REFRESH
    Return
  End If
  FIL$= Extension_8_064C
  If FIL$=""
    Sort FIL$(0)
    Timer=0 : RDIR=0 : Gosub REFRESH
    Return
  End If
  TYP= Extension_8_0688
  If QUICK=0
    DATE$=Mid$( Extension_8_0F0A( Extension_8_06F4 ),4)+" "+ Extension_8_0F1A( Extension_8_070E )
    COM$= Extension_8_0762
    FLAG$= Extension_8_0728( Extension_8_0742 )
  End If
  If TYP<0
    If DIONLY=0
      If KICK>36
        A= Extension_8_0300(FIL$,PAT$)
      Else
        A=-1
      End If
    Else
      A=0
    End If
    If A
      MXNAMLEN=Max(MXNAMLEN,Len(FIL$))
      SIZE$= Extension_8_0EC8( Extension_8_06A2 ,7)
      Inc NUMFIL
      If QUICK
        FIL$(NUMFIL)="-"+Upper$(FIL$)+Chr$(0)+SIZE$+" "+FIL$+Chr$(0)
      Else
        SOR$="-"+Upper$(FIL$)+Chr$(0)+SIZE$+" "+FIL$+Chr$(0)+DATE$+" "+FLAG$+" "+COM$
        FIL$(NUMFIL)=SOR$
      End If
    End If
  Else
    MXNAMLEN=Max(MXNAMLEN,Len(FIL$))
    Inc NUMFIL
    If QUICK
      FIL$(NUMFIL)=" "+Upper$(FIL$)+Chr$(0)+"  <Dir> "+FIL$+Chr$(0)
    Else
      SOR$=" "+Upper$(FIL$)+Chr$(0)+"  <Dir> "+FIL$+Chr$(0)+DATE$+" "+FLAG$+" "+COM$
      FIL$(NUMFIL)=SOR$
    End If
  End If
Return
End Proc
Procedure REQUEST[T$,OP$]
  Dim LIN$(10)
  OPT=1 : OTH=TH
  For A=1 To Len(OP$)
    If Mid$(OP$,A,1)="|" Then Inc OPT
  Next
  If Screen=-1
    TH=8
    SX=Max(Len(OP$)*8+OPT*32+8+15,320) and $FE0
    LPR=SX/8-2
  Else
    SX=Max(Text Length(OP$)+OPT*32+8+15,320) and $FE0
    LPR=SX/Text Length("M")-2
  End If
  LI=0 : LP=1 : LILE=0
  For A=1 To Len(T$)
    P=Asc(Mid$(T$,A,1))
    Inc LILE
    If LILE>LPR
      LIN$(LI)=Mid$(T$,LP,SP-LP+1)
      LP=SP+2 : LILE=A-LP
      Inc LI
    End If
    If P=32 Then SP=A-1
    If P=167 Then LILE=LPR+2 : SP=A-1
  Next
  LIN$(LI)=Mid$(T$,LP) : Inc LI
  NBLI=LI-1
  SY=32+LI*TH
  If Screen=-1
    SN=0
    Screen Open SN,SX,SY,4,$8000 : Screen Hide
    Curs Off : Flash Off : Paper 2 : Pen 1 : Cls 0
    Screen Display SN,288-SX/4,168-SY/2+Ntsc*28,SX,SY
    Palette 0,$FFF,$AAA,$666
    Colour 17,$BDF : Colour 18,$6F : Colour 19,$12
    Screen Show
    Gr Writing 0
    Wait Vbl : Limit Mouse
    OLDSCR=-1
    XP=0 : YP=0
  Else
    If Screen Height<SY or Screen Width<SX or Screen Colour<4
      For A=0 To 7
        Trap Screen A
        If Errtrap : SN=A : Exit : End If
      Next
      OLDSCR=Screen
      Screen Open SN,SX,SY,4,$8000 : Screen Hide
      Curs Off : Flash Off : Paper 2 : Pen 1 : Cls 0
      Screen Display SN,288-SX/4,168-SY/2+Ntsc*28,SX,SY
      Get Palette OLDSCR
      Screen Show
      Gr Writing 0
      Wait Vbl : Limit Mouse
      XP=0 : YP=0
    Else
      XP=(Screen Width-SX)/2
      YP=(Screen Height-SY)/2
      SN=-1
      Get Cblock 9,XP-4,YP-2,SX+16,SY+4
      DRABOX[XP-4,YP-2,XP+SX+3,YP+SY+1,0]
      DRABOX[XP-2,YP-1,XP+SX+1,YP+SY,1]
      Limit Mouse X Hard(XP),Y Hard(YP) To X Hard(XP+SX-1),Y Hard(YP+SY-1)
    End If
  End If
  FILBOX[XP,YP,XP+SX-1,YP+SY-1,0]
  For A=0 To NBLI
    TEX[XP+4,YP+4+A*TH,XP+SX-5,YP+12+A*TH,LIN$(A)]
  Next
  OP=0
  For A=1 To OPT
    NP=Instr(OP$,"|",OP+1) : If NP=0 Then NP=Len(OP$)+1
    T$=Mid$(OP$,OP+1,NP-OP-1)
    X1=XP+4+((A-1)*(SX-6))/OPT
    X2=XP+1+(A*(SX-6))/OPT
    DEFTEX[15+A,X1,YP+SY-TH-14,X2,YP+SY-3,T$,1]
    OP=NP
  Next
  OMK=0
  Do
    Repeat : Multi Wait : Until Amos Here
    XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse) : MK=Mouse Key : I$=Inkey$
    BT=0
    If MK=1 and OMK<>1
      CHKMOUSE[XM,YM,16,15+OPT]
      BT=Param
    End If
    Exit If BT
    OMK=MK
  Loop
  For A=1 To OPT
    DISGAD[15+A]
  Next
  Limit Mouse
  If SN>-1
    Screen Close SN
    If OLDSCR>-1
      Screen OLDSCR
    End If
  Else
    Put Cblock 9
    Del Cblock 9
  End If
  TH=OTH
End Proc[BT-16]
Procedure NUMENT[T$,OP$,DEFNUM,LOWER,UPPER]
  Dim LIN$(10)
  OPT=1 : OTH=TH
  For A=1 To Len(OP$)
    If Mid$(OP$,A,1)="|" Then Inc OPT
  Next
  If Screen=-1
    TH=8
    SX=Max(Len(OP$)*8+OPT*32+8+15,320) and $FE0
    LPR=SX/8-2
  Else
    SX=Max(Text Length(OP$)+OPT*32+8+15,320) and $FE0
    LPR=SX/Text Length("M")-2
  End If
  LI=0 : LP=1 : LILE=0
  For A=1 To Len(T$)
    P=Asc(Mid$(T$,A,1))
    Inc LILE
    If LILE>LPR
      LIN$(LI)=Mid$(T$,LP,SP-LP+1)
      LP=SP+2 : LILE=A-LP
      Inc LI
    End If
    If P=32 Then SP=A-1
    If P=167 Then LILE=LPR+2 : SP=A-1
  Next
  LIN$(LI)=Mid$(T$,LP) : Inc LI
  NBLI=LI-1
  SY=48+LI*TH
  If Screen=-1
    SN=0
    Screen Open SN,SX,SY,4,$8000 : Screen Hide
    Curs Off : Flash Off : Paper 2 : Pen 1 : Cls 0
    Screen Display SN,288-SX/4,168-SY/2+Ntsc*28,SX,SY
    Palette 0,$FFF,$AAA,$666
    Colour 17,$BDF : Colour 18,$6F : Colour 19,$12
    Screen Show
    Gr Writing 0
    Wait Vbl : Limit Mouse
    OLDSCR=-1
    XP=0 : YP=0
  Else
    If Screen Height<SY or Screen Width<SX or Screen Colour<4
      For A=0 To 7
        Trap Screen A
        If Errtrap : SN=A : Exit : End If
      Next
      OLDSCR=Screen
      Screen Open SN,SX,SY,4,$8000 : Screen Hide
      Curs Off : Flash Off : Paper 2 : Pen 1 : Cls 0
      Screen Display SN,288-SX/4,168-SY/2+Ntsc+28,SX,SY
      Get Palette OLDSCR
      Screen Show
      Gr Writing 0
      Wait Vbl : Limit Mouse
      XP=0 : YP=0
    Else
      XP=(Screen Width-SX)/2
      YP=(Screen Height-SY)/2
      SN=-1
      Get Cblock 9,XP-4,YP-2,SX+16,SY+4
      DRABOX[XP-4,YP-2,XP+SX+3,YP+SY+1,0]
      DRABOX[XP-2,YP-1,XP+SX+1,YP+SY,1]
      Limit Mouse X Hard(XP),Y Hard(YP) To X Hard(XP+SX-1),Y Hard(YP+SY-1)
    End If
  End If
  FILBOX[XP,YP,XP+SX-1,YP+SY-1,0]
  For A=0 To NBLI
    TEX[XP+4,YP+4+A*TH,XP+SX-5,YP+12+A*TH,LIN$(A)]
  Next
  DEFTEX[16,XP+4,YP+SY-TH*2-18,XP+SX-5,YP+SY-TH-16,"{"+Mid$(Str$(DEFNUM),2),7]
  OP=0
  For A=1 To OPT
    NP=Instr(OP$,"|",OP+1) : If NP=0 Then NP=Len(OP$)+1
    T$=Mid$(OP$,OP+1,NP-OP-1)
    X1=XP+4+((A-1)*(SX-6))/OPT
    X2=XP+1+(A*(SX-6))/OPT
    DEFTEX[16+A,X1,YP+SY-TH-14,X2,YP+SY-3,T$,1]
    OP=NP
  Next
  OMK=0
  STRGAD[16,""]
  Do
    Repeat : Multi Wait : Until Amos Here
    XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse) : MK=Mouse Key : I$=Inkey$
    BT=17
    If I$<>""
      If I$<" " or(I$>="0" and I$<="9")
        If Not(I$="0" and NUM=0)
          STRGAD[16,I$]
          Exit If Param=-1
        End If
      End If
    End If
    NUM=Val(Mid$(FB$(16),2))
    If NUM<LOWER
      NUM=LOWER
      NEWTEX[16,"{"+Mid$(Str$(NUM),2)]
      STRGAD[16,""]
    End If
    If NUM>UPPER
      NUM=UPPER
      NEWTEX[16,"{"+Mid$(Str$(NUM),2)]
      STRGAD[16,""]
    End If
    BT=0
    If MK=1 and OMK<>1
      CHKMOUSE[XM,YM,16,16+OPT]
      BT=Param
    End If
    Exit If BT>16
    OMK=MK
  Loop
  For A=1 To OPT+1
    DISGAD[15+A]
  Next
  Limit Mouse
  If SN>-1
    Screen Close SN
    If OLDSCR>-1
      Screen OLDSCR
    End If
  Else
    Put Cblock 9
    Del Cblock 9
  End If
  TH=OTH
  A$= Extension_8_0EB8(BT-17,1)+Mid$(Str$(NUM),2)
End Proc[A$]
Procedure TXTENT[T$,OP$,DEFTXT$,NUMLET]
  Dim LIN$(10)
  OPT=1 : OTH=TH
  For A=1 To Len(OP$)
    If Mid$(OP$,A,1)="|" Then Inc OPT
  Next
  If Screen=-1
    TH=8
    SX=Max(Len(OP$)*8+OPT*32+8+15,320) and $FE0
    LPR=SX/8-2
  Else
    SX=Max(Text Length(OP$)+OPT*32+8+15,320) and $FE0
    LPR=SX/Text Length("M")-2
  End If
  LI=0 : LP=1 : LILE=0
  For A=1 To Len(T$)
    P=Asc(Mid$(T$,A,1))
    Inc LILE
    If LILE>LPR
      LIN$(LI)=Mid$(T$,LP,SP-LP+1)
      LP=SP+2 : LILE=A-LP
      Inc LI
    End If
    If P=32 Then SP=A-1
    If P=167 Then LILE=LPR+2 : SP=A-1
  Next
  LIN$(LI)=Mid$(T$,LP) : Inc LI
  NBLI=LI-1
  SY=48+LI*TH
  If Screen=-1
    SN=0
    Screen Open SN,SX,SY,4,$8000 : Screen Hide
    Curs Off : Flash Off : Paper 2 : Pen 1 : Cls 0
    Screen Display SN,288-SX/4,168-SY/2+Ntsc*28,SX,SY
    Palette 0,$FFF,$AAA,$666
    Colour 17,$BDF : Colour 18,$6F : Colour 19,$12
    Screen Show
    Gr Writing 0
    Wait Vbl : Limit Mouse
    OLDSCR=-1
    XP=0 : YP=0
  Else
    If Screen Height<SY or Screen Width<SX or Screen Colour<4
      For A=0 To 7
        Trap Screen A
        If Errtrap : SN=A : Exit : End If
      Next
      OLDSCR=Screen
      Screen Open SN,SX,SY,4,$8000 : Screen Hide
      Curs Off : Flash Off : Paper 2 : Pen 1 : Cls 0
      Screen Display SN,288-SX/4,168-SY/2+Ntsc*28,SX,SY
      Get Palette OLDSCR
      Screen Show
      Gr Writing 0
      Wait Vbl : Limit Mouse
      XP=0 : YP=0
    Else
      XP=(Screen Width-SX)/2
      YP=(Screen Height-SY)/2
      SN=-1
      Get Cblock 9,XP-4,YP-2,SX+16,SY+4
      DRABOX[XP-4,YP-2,XP+SX+3,YP+SY+1,0]
      DRABOX[XP-2,YP-1,XP+SX+1,YP+SY,1]
      Limit Mouse X Hard(XP),Y Hard(YP) To X Hard(XP+SX-1),Y Hard(YP+SY-1)
    End If
  End If
  FILBOX[XP,YP,XP+SX-1,YP+SY-1,0]
  For A=0 To NBLI
    TEX[XP+4,YP+4+A*TH,XP+SX-5,YP+12+A*TH,LIN$(A)]
  Next
  DEFTEX[16,XP+4,YP+SY-TH*2-18,XP+SX-5,YP+SY-TH-16,"{"+DEFTXT$,7]
  OP=0
  For A=1 To OPT
    NP=Instr(OP$,"|",OP+1) : If NP=0 Then NP=Len(OP$)+1
    T$=Mid$(OP$,OP+1,NP-OP-1)
    X1=XP+4+((A-1)*(SX-6))/OPT
    X2=XP+1+(A*(SX-6))/OPT
    DEFTEX[16+A,X1,YP+SY-TH-14,X2,YP+SY-3,T$,1]
    OP=NP
  Next
  OMK=0
  STRGAD[16,""]
  Do
    Repeat : Multi Wait : Until Amos Here
    XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse) : MK=Mouse Key : I$=Inkey$
    BT=17
    If I$<>""
      STRGAD[16,I$]
      Exit If Param=-1
    End If
    TXT$=Mid$(FB$(16),2)
    If Len(TXT$)>NUMLET
      NEWTEX[16,"{"+Left$(TXT$,NUMLET)]
      STRGAD[16,""]
    End If
    BT=0
    If MK=1 and OMK<>1
      CHKMOUSE[XM,YM,16,16+OPT]
      BT=Param
    End If
    Exit If BT>16
    OMK=MK
  Loop
  For A=1 To OPT+1
    DISGAD[15+A]
  Next
  Limit Mouse
  If SN>-1
    Screen Close SN
    If OLDSCR>-1
      Screen OLDSCR
    End If
  Else
    Put Cblock 9
    Del Cblock 9
  End If
  TH=OTH
  A$= Extension_8_0EB8(BT-17,1)+TXT$
End Proc[A$]
Procedure CHKMOUSE[XM,YM,LL,UL]
  For BT=LL To UL
    If XM=>FB(BT,0) and XM<=FB(BT,2) and YM=>FB(BT,1) and YM<=FB(BT,3) and(FB(BT,4) and 1) Then Exit
  Next
  If BT>UL Then Pop Proc[0]
  If FB(BT,4) and 2 Then Pop Proc[BT]
  OST=-1 : AA=0
  ST= Extension_8_093A(FB(BT,4) and 4,2)
  Repeat
    Multi Wait
    XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse) : MK=Mouse Key : I$=Inkey$
    If XM=>FB(BT,0) and XM<=FB(BT,2) and YM=>FB(BT,1) and YM<=FB(BT,3) Then A=1 Else A=0
    If AA<>A Then AA=A : ST=1-ST
    If OST<>ST
      If ST
        PUSHGAD[BT]
      Else
        RELEGAD[BT]
      End If
      OST=ST
    End If
  Until MK<>1
  If A=0 Then Pop Proc[0]
  If ST
    RELEGAD[BT]
  Else
    PUSHGAD[BT]
  End If
End Proc[BT]
Procedure DEFTEX[BT,X1,Y1,X2,Y2,T$,FL]
  TEXBOX[X1,Y1,X2,Y2, Extension_8_093A(FL and 4,2),T$]
  DEFGAD[BT,X1,Y1,X2,Y2,FL]
  FB$(BT)=T$
End Proc
Procedure DEFBOX[BT,X1,Y1,X2,Y2,FL]
  FILBOX[X1,Y1,X2,Y2, Extension_8_093A(FL and 4,2)]
  DEFGAD[BT,X1,Y1,X2,Y2,FL]
End Proc
Procedure DEFGAD[BT,X1,Y1,X2,Y2,FL]
  FB(BT,0)=X1 : FB(BT,1)=Y1
  FB(BT,2)=X2 : FB(BT,3)=Y2
  FB(BT,4)=FL
  FB$(BT)=""
End Proc
Procedure DEAGAD[BT]
  If(FB(BT,4) and 1)=0 Then Pop Proc
  FB(BT,4)=FB(BT,4) and $FE
  Set Pattern 2
  Ink 3 : Bar FB(BT,0),FB(BT,1) To FB(BT,2),FB(BT,3)
  Set Pattern 0
End Proc
Procedure ACTGAD[BT]
  If FB(BT,4) and 1 Then Pop Proc
  CLRGAD[BT]
  FB(BT,4)=FB(BT,4) or 1
  If FB$(BT)<>""
    TEXBOX[FB(BT,0),FB(BT,1),FB(BT,2),FB(BT,3), Extension_8_093A(FB(BT,4) and 4,2),FB$(BT)]
  Else
    DRABOX[FB(BT,0),FB(BT,1),FB(BT,2),FB(BT,3), Extension_8_093A(FB(BT,4) and 4,2)]
  End If
End Proc
Procedure DISGAD[BT]
  FB(BT,4)=FB(BT,4) and $FE
End Proc
Procedure ENAGAD[BT]
  FB(BT,4)=FB(BT,4) or 1
End Proc
Procedure CLRGAD[BT]
  FB(BT,4)=FB(BT,4) and $FE
  Ink 2 : Bar FB(BT,0),FB(BT,1) To FB(BT,2),FB(BT,3)
End Proc
Procedure PUSHGAD[BT]
  DRABOX[FB(BT,0),FB(BT,1),FB(BT,2),FB(BT,3),1]
End Proc
Procedure RELEGAD[BT]
  DRABOX[FB(BT,0),FB(BT,1),FB(BT,2),FB(BT,3),0]
End Proc
Procedure FILBOX[X1,Y1,X2,Y2,SE]
  Ink 2 : Bar X1+2,Y1+1 To X2-2,Y2-1
   Extension_8_0388 X1,Y2,2
   Extension_8_0388 X2,Y1,2
  Ink 1+SE*2 : Draw X1,Y2-1 To X1,Y1 : Draw To X2-1,Y1 : Draw X1+1,Y2-1 To X1+1,Y1
  Ink 3-SE*2 : Draw X1+1,Y2 To X2,Y2 : Draw To X2,Y1+1 : Draw X2-1,Y2 To X2-1,Y1+1
End Proc
Procedure NEWTEX[BT,T$]
  FB$(BT)=T$
  TEX[FB(BT,0)+1,FB(BT,1),FB(BT,2)-1,FB(BT,3),T$]
End Proc
Procedure TEXBOX[X1,Y1,X2,Y2,SE,T$]
  TEX[X1+1,Y1,X2-1,Y2,T$]
   Extension_8_0388 X1,Y2,2 : Extension_8_0388 X2,Y1,2
  Ink 1+SE*2 : Draw X1,Y2-1 To X1,Y1 : Draw To X2-1,Y1 : Draw X1+1,Y2-1 To X1+1,Y1
  Ink 3-SE*2 : Draw X1+1,Y2 To X2,Y2 : Draw To X2,Y1+1 : Draw X2-1,Y2 To X2-1,Y1+1
End Proc
Procedure TEX[X1,Y1,X2,Y2,T$]
  If Asc(T$)=123
    M=1 : T$=Mid$(T$,2)
  Else
    If Asc(T$)=125
      M=2 : T$=Mid$(T$,2)
    Else
      M=0
    End If
  End If
  TL=Text Length(T$)
  While TL>(X2-X1)-4
    T$=Left$(T$,Len(T$)-1)
    TL=Text Length(T$)
  Wend
  If M=1
    X=X1+4 : Y=Y1+1
  Else
    If M=2
      X=X2-Text Length(T$)-2 : Y=Y1+1
    Else
      X=(X1+X2-TL)/2 : Y=(Y1+Y2-TH+1)/2
    End If
  End If
  If Y2>0 Then Ink 2 : Bar X1+1,Y1+1 To X2-1,Y2-1
  Ink 0 : Text X,Y+Text Base,T$
End Proc
Procedure TEX2[X1,Y1,X2,Y2,T$]
  If Asc(T$)=123
    M=1 : T$=Mid$(T$,2)
  Else
    If Asc(T$)=125
      M=2 : T$=Mid$(T$,2)
    Else
      M=0
    End If
  End If
  TL=Text Length(T$)
  While TL>(X2-X1)-4
    T$=Left$(T$,Len(T$)-1)
    TL=Text Length(T$)
  Wend
  If M=1
    X=X1+4 : Y=Y1+1
  Else
    If M=2
      X=X2-Text Length(T$)-2 : Y=Y1+1
    Else
      X=(X1+X2-TL)/2 : Y=(Y1+Y2-TH+1)/2
    End If
  End If
  If Y2>0 Then Ink 2 : Bar X1+1,Y1+1 To X2-1,Y2-1
  Ink 1 : Text X,Y+Text Base,T$
End Proc
Procedure DRABOX[X1,Y1,X2,Y2,SE]
  Ink 1+SE*2 : Draw X1,Y2-1 To X1,Y1 : Draw To X2-1,Y1 : Draw X1+1,Y2-1 To X1+1,Y1
  Ink 3-SE*2 : Draw X1+1,Y2 To X2,Y2 : Draw To X2,Y1+1 : Draw X2-1,Y2 To X2-1,Y1+1
End Proc
Procedure STRGAD[BT,I$]
  Shared POS
  A$=FB$(BT)
  If I$=""
    POS=Len(A$)-1
  End If
  If I$>Chr$(31) Then A$=Left$(A$,POS+1)+I$+Mid$(A$,POS+2) : Inc POS
  If I$=Chr$(8) and POS>0 Then A$=Left$(A$,POS)+Mid$(A$,POS+2) : Dec POS
  If I$=Cleft$ and POS>0 Then Dec POS
  If I$=Cright$ and POS<Len(A$)-1 Then Inc POS
  If I$=Chr$(13)
    NEWTEX[BT,A$]
    Pop Proc[-1]
  End If
  NEWTEX[BT,A$]
  X1=FB(BT,0)+5+Text Length(Mid$(A$,2,POS)) : Y1=FB(BT,1)+1
  X2=X1+Max(Text Length(Mid$(A$,POS+2,1)),4)
  If X2<FB(BT,2)-4
    Gr Writing 2
    Ink 3 : Bar X1,Y1 To X2-1,Y1+TH-1
    Gr Writing 0
  End If
End Proc[0]
Procedure DEFCLOWIN[BT,X,Y]
  DRACLOWIN[X,Y]
  DEFGAD[BT,X,Y,X+18,Y+TH+2,1]
End Proc
Procedure DRACLOWIN[X,Y]
  FILBOX[X,Y,X+18,Y+TH+2,0]
  Ink 0 : Box 7+X,3+Y To 11+X,Y+TH-1
End Proc
Procedure DEFSCRTBK[BT,X,Y]
  DRASCRTBK[X,Y]
  DEFGAD[BT,X,Y,X+22,Y+TH+2,1]
End Proc
Procedure DRASCRTBK[X,Y]
  FILBOX[X,Y,X+22,Y+TH+2,0]
  Ink 0 : Box 4+X,2+Y To 14+X,Y+TH/2+2
  Ink 2 : Bar 8+X,Y+TH/2 To 18+X,Y+TH
  Ink 0 : Box 8+X,Y+TH/2 To 18+X,Y+TH
End Proc
Procedure DEFARROWU[BT,X,Y]
  DRAARROWU[X,Y]
  DEFGAD[BT,X,Y,X+17,Y+8,3]
End Proc
Procedure DRAARROWU[X,Y]
  DRABOX[X,Y,X+17,Y+8,0]
   Extension_8_1016 X+4,Y+6 To X+8,Y+2,0
   Extension_8_1016 X+5,Y+6 To X+8,Y+3,0
   Extension_8_1016 X+9,Y+2 To X+13,Y+6,0
   Extension_8_1016 X+9,Y+3 To X+12,Y+6,0
End Proc
Procedure DEFARROWD[BT,X,Y]
  DRAARROWD[X,Y]
  DEFGAD[BT,X,Y,X+17,Y+8,3]
End Proc
Procedure DRAARROWD[X,Y]
  DRABOX[X,Y,X+17,Y+8,0]
   Extension_8_1016 X+4,Y+2 To X+8,Y+6,0
   Extension_8_1016 X+5,Y+2 To X+8,Y+5,0
   Extension_8_1016 X+9,Y+6 To X+13,Y+2,0
   Extension_8_1016 X+9,Y+5 To X+12,Y+2,0
End Proc
Procedure DRAPROCBAR[BT,POS,MX]
  X1=FB(BT,0)+2 : X2=FB(BT,2)-2 : Y1=FB(BT,1)+1 : Y2=FB(BT,3)-1
  DX=X2-X1
  PX=X1+(POS*DX)/MX
  If PX>X1 and PX<X2
    Ink 0 : Bar X1,Y1 To PX,Y2
    Ink 2 : Bar PX,Y1 To X2,Y2
  End If
  If PX=X1 Then Ink 2 : Bar X1,Y1 To X2,Y2
  If PX=X2 Then Ink 0 : Bar X1,Y1 To X2,Y2
End Proc
Procedure DRASLIDER[BT,LINOFF,PAG,NUMLIN,NB]
  D=(FB(BT,3)-FB(BT,1))-4
  Y1=(LINOFF*D)/Max(NUMLIN,PAG)+FB(BT,1)+2
  Y2=((LINOFF+PAG)*D)/Max(NUMLIN,PAG)+FB(BT,1)+2
  DEFGAD[NB,FB(BT,0)+4,Y1,FB(BT,2)-4,Y2,3]
  Ink 2
  If Y1>FB(BT,1)+2 Then Bar FB(BT,0)+4,FB(BT,1)+1 To FB(BT,2)-4,Y1-1
  If Y2<FB(BT,3)-2 Then Bar FB(BT,0)+4,Y2+1 To FB(BT,2)-4,FB(BT,3)-1
  If Y2-Y1>0
    Ink 0 : Bar FB(BT,0)+4,Y1 To FB(BT,2)-4,Y2
  Else
     Extension_8_1016 FB(BT,0)+4,Y1 To FB(BT,2)-4,Y2,0
  End If
End Proc
Procedure DRAGSLIDER[BT,Y,PAG,NUMLIN,NB]
  Y1=FB(NB,1) : Y2=FB(NB,3) : D=Y2-Y1
  Y1=Min(Max(FB(BT,1)+2,Y),FB(BT,3)-2-D)
  Y2=Y1+D : FB(NB,1)=Y1 : FB(NB,3)=Y2
  Ink 2
  If Y1>FB(BT,1)+2 Then Bar FB(BT,0)+4,FB(BT,1)+1 To FB(BT,2)-4,Y1-1
  If Y2<FB(BT,3)-2 Then Bar FB(BT,0)+4,Y2+1 To FB(BT,2)-4,FB(BT,3)-1
  If Y2-Y1>0
    Ink 1 : Bar FB(BT,0)+4,Y1 To FB(BT,2)-4,Y2
  Else
     Extension_8_1016 FB(BT,0)+4,Y1 To FB(BT,2)-4,Y2,1
  End If
  D=FB(BT,3)-FB(BT,1)-4
  L=Min(((Y1-FB(BT,1)-2)*Max(NUMLIN,PAG)+D/2)/D,NUMLIN-PAG)
End Proc[L]